ProgressBar columns

Drawing of a ProgressBar

Grid doesn't allow customizing column to show ProgressBar shaped image, but there is a procedure DrawProgressBarEh in the ToolCtrlsEh module. You can use it to draw image of ProgressBar when an event of custom drawing of a Grid's cell is used.

Below you can see an example of using of the DrawProgressBarEh procedure:

procedure TForm1.DBGridEh6Columns3AdvDrawDataCell(Sender: TCustomDBGridEh;
  Cell, AreaCell: TGridCoord; Column: TColumnEh; const ARect: TRect;
  var Params: TColCellParamsEh; var Processed: Boolean);
begin
  Sender.DefaultDrawColumnDataCell(Cell, AreaCell, Column, ARect, Params);

  DrawProgressBarEh(mtTable1.FieldByName('ItemsTotal').AsFloat, 0, 50000, 
     Sender.Canvas, ARect, clSkyBlue, cl3DDkShadow, clNone);
  Processed := True;
end;

Procedure DrawProgressBarEh has next parameters:

CurrentValue: Double;

Current value of the DrawProgress position.

MinValue: Double;

Minimum value of the DrawProgress position. The value is used to calculate the current percentage.

MaxValue: Double;

Maxinum value of the DrawProgress position. The value is used to calculate the current percentage.

Canvas: TCanvas;

The canvas that is used for rendering. Here you need to pass the canvas of the grid.

const Rect: TRect;

The rectangle inside which the DrawProgress is drawn.

Color: TColor;

The color of the progress bar that paints the completed part of the process.

FrameColor: TColor;

The border color of the completed part of the progress bar.

BackgroundColor: TColor;

The color of the entire background of the progress bar.

const PBParPtr: PProgressBarParamsEh = nil

Pointer to advanced rendering options for the progress bar. This is not a required parameter. You can also pass nil as a parameter to indicate that advanced options are not used.

Extended options are of the following type:

PProgressBarParamsEh = ^TProgressBarParamsEh;
  TProgressBarParamsEh = record ...

TProgressBarParamsEh has the following fields:

ShowText: Boolean;

Whether to show the progress percentage value.

TextType: TProgressBarTextTypeEh;

TProgressBarTextTypeEh = (pbttAsValue, pbttAsPercent);

pbttAsValue - display the value passed in the CurrentValue parameter.

pbttAsPercent - Display the value as a percentage calculated using the formula MaxValue - MinValue = 100%.

TextDecimalPlaces: Byte;

Round the value to a decimal point.

TextAlignment : TAlignment;

Percent text alignment.

FrameFigureType: TProgressBarFrameFigureTypeEh;

TProgressBarFrameFigureTypeEh = (pbfftRectangle, pbfftRoundRect);

Border type.

pbfftRectangle - Rectangle.

pbfftRoundRect - Rectangle with rounded corners.

FrameSizeType: TProgressBarFrameSizeTypeEh;

TProgressBarFrameSizeTypeEh = (pbfstFull, pbfstVal);

The drawing area of the border.

pbfstFull - A border is drawn around the entire area of the progress bar.

pbfstVal - The border is drawn around the completed area of the progress bar.

Indent: Byte

The size of the indent from the cell borders.

FontName: String;

The name of the font to display the progress percentage.

FontColor: TColor;

Font color.

FontSize: Integer;

Font size.

FontStyle: TFontStyles;

Font style.

Code example:

Full Demo code

procedure TForm1.DBGridEh1Columns5AdvDrawDataCell(Sender: TCustomDBGridEh; Cell,
  AreaCell: TGridCoord; Column: TColumnEh; const ARect: TRect;
  var Params: TColCellParamsEh; var Processed: Boolean);
var
  Prm: TProgressBarParamsEh;
begin
  Sender.DefaultDrawColumnDataCell(Cell, AreaCell, Column, ARect, Params);

  Prm.ShowText := True;
  Prm.TextType := TProgressBarTextTypeEh.pbttAsPercent;
  Prm.TextDecimalPlaces := 1;
  Prm.TextAlignment := TAlignment.taCenter;
  Prm.FrameFigureType := TProgressBarFrameFigureTypeEh.pbfftRectangle;
  Prm.FrameSizeType := TProgressBarFrameSizeTypeEh.pbfstFull;
  Prm.Indent := 2;
  Prm.FontName := '';
  Prm.FontColor := clDefault;
  Prm.FontSize := Sender.Canvas.Font.Size - 1;
  Prm.FontStyle := [];

  DrawProgressBarEh(MemTableEh1.FieldByName('ItemsTotal').AsFloat, 0, 50000,
    Sender.Canvas, ARect, clSkyBlue, cl3DDkShadow, clNone,
    @Prm);
  Processed := True;
end;